home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / LANG / GNUST / !GNUst / st / String < prev    next >
Text File  |  1991-09-13  |  6KB  |  246 lines
  1. "======================================================================
  2. |
  3. |   String Method Definitions
  4. |
  5.  ======================================================================"
  6.  
  7.  
  8. "======================================================================
  9. |
  10. | Copyright (C) 1990, 1991 Free Software Foundation, Inc.
  11. | Written by Steve Byrne.
  12. |
  13. | This file is part of GNU Smalltalk.
  14. |
  15. | GNU Smalltalk is free software; you can redistribute it and/or modify it
  16. | under the terms of the GNU General Public License as published by the Free
  17. | Software Foundation; either version 1, or (at your option) any later version.
  18. | 
  19. | GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
  20. | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  21. | FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  22. | details.
  23. | 
  24. | You should have received a copy of the GNU General Public License along with
  25. | GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
  26. | Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  
  27. |
  28.  ======================================================================"
  29.  
  30.  
  31. "
  32. |     Change Log
  33. | ============================================================================
  34. | Author       Date       Change 
  35. | sbb         12 Sep 91      Fixed second fileName method definition to be
  36. |              filePos.
  37. |
  38. | sbyrne      3 Sep 89      added asString for method source package
  39. |
  40. | sbyrne     25 Apr 89      created.
  41. |
  42. "
  43.  
  44. ArrayedCollection variableByteSubclass: #String
  45.           instanceVariableNames: ''
  46.           classVariableNames: ''
  47.           poolDictionaries: ''
  48.           category: nil.
  49.  
  50. String comment: 
  51. 'My instances represent string data types.  I provide accessing and
  52. manipulation methods for string data types.' !
  53.  
  54. !String class methodsFor: 'basic'!
  55.  
  56. fromString: aString
  57.     " ### probably should use regular copy"
  58.     ^aString copyFrom: 1 to: aString size
  59. !
  60.  
  61. readFrom: aStream
  62.     | str newChar |
  63.     str _ WriteStream on: (String new: 0).
  64.     aStream do:            " ### Is this risky, doing a next inside? "
  65.         [ :char | char == $'
  66.                   ifTrue: [ newChar _ aStream next.
  67.                           newChar == $' ifFalse: [ str nextPut: $' ].
  68.                 str nextPut: newChar ]
  69.                       ifFalse: [ str nextPut: char ]
  70.     ].
  71.     ^str contents
  72. !!
  73.  
  74.  
  75.  
  76. !String methodsFor: 'comparing'!
  77.  
  78. < aString
  79.     "Return true if the receiver is less than aString, ignoring case
  80.     differences."
  81.     self >= aString ifTrue: [ ^false ]
  82.                     ifFalse: [ ^true ]
  83. !
  84.  
  85. > aString
  86.     "Return true if the receiver is greater than aString, ignoring case
  87.     differences."
  88.     self <= aString ifTrue: [ ^false ]
  89.                     ifFalse: [ ^true ]
  90. !
  91.  
  92. <= aString
  93.     "Returns true if the receiver is less than or equal to aString,
  94.     ignoring case differences.  If is receiver is an initial substring of
  95.     aString, it is considered to be less than aString."
  96.     | c1 c2 |
  97.     " Scan self and aString until a character is clearly greater or lesser
  98.       (All preceding characters must have been equal).  If the end is reached,
  99.       one of the strings is a possibly improper initial substring of the other,
  100.       and for the receiver to be less than aString, it must be the initial
  101.       substring."
  102.     1 to: (self size min: aString size) do:
  103.         [ :i | c1 _ (self at: i) asLowercase.
  104.            c2 _ (aString at: i) asLowercase.
  105.            c1 < c2 ifTrue: [ ^true ].
  106.            c1 > c2 ifTrue: [ ^false ] ].
  107.     ^self size <= aString size
  108. !
  109.  
  110. >= aString
  111.     "Returns true if the receiver is greater than or equal to aString,
  112.     ignoring case differences.  If is aString is an initial substring of
  113.     the receiver, it is considered to be less than the receiver."
  114.     | c1 c2 |
  115.     1 to: (self size min: aString size) do:
  116.         [ :i | c1 _ (self at: i) asLowercase.
  117.            c2 _ (aString at: i) asLowercase.
  118.            c1 < c2 ifTrue: [ ^false ].
  119.            c1 > c2 ifTrue: [ ^true ] ].
  120.     ^self size >= aString size
  121. !
  122.  
  123.  
  124.  
  125. sameAs: aString
  126.     "Returns true if the receiver is the same string as aString, ignoring
  127.     case differences."
  128.     self size ~= aString size ifTrue: [ ^false ].
  129.     1 to: self size do:
  130.         [ :i | (self at: i) asLowercase ~= (aString at: i) asLowercase
  131.             ifTrue: [ ^false ] ].
  132.     ^true
  133. !
  134.  
  135.  
  136. match: aString
  137.     ^self asLowercase matchSubstring: 1 in: aString asLowercase at: 1
  138. !!
  139.  
  140.  
  141.  
  142. !String methodsFor: 'converting'!
  143.  
  144. asUppercase
  145.     "Returns a copy of self as an uppercase string"
  146.     | newStr |
  147.     newStr _ self species new: self size.
  148.     1 to: self size do:
  149.         [ :i | newStr at: i put: (self at: i) asUppercase ].
  150.     ^newStr
  151. !
  152.  
  153. asLowercase
  154.     "Returns a copy of self as a lowercase string"
  155.     | newStr |
  156.     newStr _ self species new: self size.
  157.     1 to: self size do:
  158.         [ :i | newStr at: i put: (self at: i) asLowercase ].
  159.     ^newStr
  160. !
  161.  
  162. asString
  163.     "But I already am a string!  Really!"
  164.     ^self
  165. !
  166.  
  167. fileName
  168.     "But I don't HAVE a file name!"
  169.     ^nil
  170. !
  171.  
  172. filePos
  173.     "But I don't HAVE a file position!"
  174.     ^nil
  175. !
  176.  
  177. asSymbol
  178.     "Returns the symbol corresponding to the string"
  179.     ^Symbol intern: self
  180. !!
  181.  
  182.  
  183.  
  184. !String methodsFor: 'copying'!
  185.  
  186. shallowCopy
  187.     | newStr |
  188.     newStr _ self species new: self size.
  189.     1 to: self size do:
  190.         [ :i | newStr at: i put: (self at: i) ].
  191.     ^newStr
  192. !
  193.  
  194. deepCopy
  195.     ^self shallowCopy
  196. !!
  197.  
  198.  
  199.  
  200.  
  201. !String methodsFor: 'printing'!
  202.  
  203. printOn: aStream
  204.     ^self do: 
  205.     [ :char | aStream nextPut: char ] "this seems too primitive"
  206. !!
  207.  
  208.  
  209.  
  210. !String methodsFor: 'storing'!
  211.  
  212. storeOn: aStream
  213.     aStream nextPut: $'.
  214.     self do:
  215.         [ :char | char == $' ifTrue: [ aStream nextPut: char ].
  216.               aStream nextPut: char ].
  217.     aStream nextPut: $'
  218. !!
  219.  
  220.  
  221.  
  222. !String methodsFor: 'private'!
  223.  
  224. matchSubstring: p in: aString at: s
  225.     | pc |
  226.     p > self size
  227.         ifTrue: [ ^s > aString size ].
  228.     pc _ self at: p.
  229.     pc = $*
  230.         ifTrue: [ s to: (aString size) + 1 do:
  231.                 [ :ss | (self matchSubstring: p + 1
  232.                           in: aString
  233.                   at: ss)
  234.                     ifTrue: [ ^true ] ].
  235.           ^false ].
  236.     s > aString size ifTrue: [ ^false ].
  237.     pc = $#
  238.         ifTrue: [ ^self matchSubstring: p + 1 in: aString at: s + 1 ].
  239.  
  240.     pc = (aString at: s)
  241.         ifTrue: [ ^self matchSubstring: p + 1 in: aString at: s + 1 ].
  242.     ^false
  243. !!
  244.  
  245.  
  246.